OpenEdge Development:<br />Progress 4GL Reference CURRENT-VALUE function


CURRENT-VALUE ( `sequence` [ , `logical-dbname` ] )

An identifier that specifies the name of a sequence defined in the Data Dictionary.

An identifier that specifies the logical name of the database in which the sequence is defined. The database must be connected. You can omit this parameter if the sequence name is unambiguous. If a sequence with this name exists in more than one connected database, then you must specify logical-dbname.

The following example finds the current value of the next-cust-num sequence and then looks for orders with that customer number:

r-curval.p
DEFINE VARIABLE cur-cust LIKE customer.cust-num NO-UNDO. cur-cust = CURRENT-VALUE(next-cust-num). IF CAN-FIND(FIRST order WHERE order.cust-num = cur-cust) THEN FOR EACH order WHERE order.cust-num = cur-cust, EACH order-line OF order NO-LOCK BREAK BY order.order-num: IF FIRST-OF(order.order-num) THEN DISPLAY order.order-num order.order-date order.cust-num WITH FRAME order-info CENTERED ROW 2 1 COL. DISPLAY order-line. END. ELSE DO: FIND FIRST customer WHERE customer.cust-num = cur-cust NO-LOCK NO-ERROR. IF AVAILABLE customer THEN MESSAGE "No Orders Exist for Customer " + customer.name + ", " + string(customer.cust-num) VIEW-AS ALERT-BOX INFORMATION BUTTONS OK TITLE "No Orders". ELSE MESSAGE "Customer number" cur-cust "does not exist." VIEW-AS ALERT-BOX INFORMATION BUTTONS OK TITLE "No Customer". END.

r-curval.p

DEFINE VARIABLE cur-cust LIKE customer.cust-num NO-UNDO.

cur-cust = CURRENT-VALUE(next-cust-num).
IF CAN-FIND(FIRST order WHERE order.cust-num = cur-cust) THEN
  FOR EACH order WHERE order.cust-num = cur-cust,
      EACH order-line OF order NO-LOCK
      BREAK BY order.order-num:
  
      IF FIRST-OF(order.order-num) THEN
        DISPLAY order.order-num order.order-date order.cust-num
          WITH FRAME order-info CENTERED ROW 2 1 COL.
   
      DISPLAY order-line.
  END.
ELSE DO:
  FIND FIRST customer WHERE customer.cust-num = cur-cust
        NO-LOCK NO-ERROR.

  IF AVAILABLE customer THEN   
     MESSAGE "No Orders Exist for Customer " + customer.name +
          ", " + string(customer.cust-num)
          VIEW-AS ALERT-BOX INFORMATION BUTTONS OK TITLE "No Orders".
  ELSE MESSAGE "Customer number" cur-cust "does not exist."
          VIEW-AS ALERT-BOX INFORMATION BUTTONS OK TITLE "No Customer".
END.

Notes

The current value of a sequence can be one of the following:

The initial value specified in the Data Dictionary.

The last value set with either the CURRENT-VALUE statement or the NEXT-VALUE function.

The Unknown value (?) if the sequence has exceeded its minimum or maximum and is not cycling.

Sequence values are stored in the database in which they are defined, and persist between each invocation of the CURRENT-VALUE statement or NEXT-VALUE function.

You cannot invoke the CURRENT-VALUE function from within a WHERE clause. Doing so generates a compiler error. To use a result from the CURRENT-VALUE function in a WHERE clause, assign the result to a variable, then use the variable in the WHERE clause.

You can use any combination of the NEXT-VALUE function, CURRENT-VALUE function, CURRENT-VALUE statement, and their dynamic versions. Use the dynamic version when you don’t know what the database name or sequence name is at runtime.

CURRENT-VALUE function

Syntax

Notes

See also